.Domino Framework

1. Pass either a database, view, or document collection as the source.
2. Request either the contents of a column number or fieldname to be returned.

'/**
' * Returns an array containing the list of values for a specific column/field for any collection of documents
' *
' * @author Peter Presnell
' * @param ClassCache   Not used
' * @param Database    NotesDatabase object, server/filepath, or replicaid id, or Nothing (current database)
' * @param View      NotesDocumentCollection, NotesView, name of view, or Nothing (All documents in database)
' * @!param Column     Column number or name of field corresponding to values to be returned
' * @return  List of values
' */
Function atfDBColumn(ClassCache As Variant, Database As Variant,View As Variant, Column As Variant) As Variant
 
 Dim iDB     As New NotesDatabase("","")  ' Database to perfrom lookup
 Dim iCollection   As Variant         ' View/Document Collection used to perfrom lookup
 Dim EntryList   As NotesViewEntryCollection  ' List of all entries in view
 Dim Entry     As NotesViewEntry      ' Current entry in view
 Dim Doc     As NotesDocument     ' Document that corresponds to current entry in view
 Dim ColumnValues As Variant
 Dim  Results     As Variant         ' Interim results
 Dim  Index     As Long         ' Counter used to loop through array
Try: 
 On Error Goto Catch
 
' Setup database/view
 
 Redim Results(0)
 Select Case Typename(Database)
 Case "NOTESDATABASE"
  Set iDB = Database
 Case "STRING"
  Call iDB.OpenByReplicaID(Session.CurrentDatabase.Server,Cstr(Database))
 Case "STRING ()"
  If (Ubound(Database) = 1) Then
   If Database(1) = "" Then Set iDB = Session.CurrentDatabase Else Call iDB.Open(Database(0),Database(1))
  End If
 End Select
 
 Select Case Typename(View)
 Case "NOTESDOCUMENTCOLLECTION"
  Set iCollection = View
 Case "NOTESVIEW"
  Set iCollection = View
  Set iDB = iCollection.Parent
 Case "OBJECT"
  If iDB Is Nothing Then Set iDB = Session.CurrentDatabase
  Set iCollection = iDB.AllDocuments
 Case "STRING"
  If (iDB Is Nothing) Then Set iDB = Session.CurrentDatabase
  Set iCollection = iDB.GetView(Cstr(View))
 Case Else
  Exit Function
 End Select
 If iCollection Is Nothing Then Error 1000, "View not found"
 
' Extract values
 
 Select Case Typename(iCollection)
 Case "NOTESDOCUMENTCOLLECTION":
  Set Doc = iCollection.GetFirstDocument
  While Not Doc Is Nothing
   Select Case Typename(Column)
   Case "INTEGER","LONG"
    If (Ubound(Doc.ColumnValues) >= Cint(Column)-1) Then
     ColumnValues = Doc.ColumnValues(Column-1)
     If (Isarray(ColumnValues)) Then
      Forall ColumnValue In ColumnValues
       Redim Preserve Results(Index&)
       Results(Index&) = ColumnValue
       Index& = Index& + 1
      End Forall
     Else
      Redim Preserve Results(Index&)
      Results(Index&) = ColumnValues
      Index& = Index& + 1
     End If
    End If
   Case "STRING"
    Redim Preserve Results(Index&)
    If (Doc.HasItem(Cstr(Column))) Then
     Results(Index&) = Doc.GetItemValue(Cstr(Column))(0)
     Index& = Index& + 1
    End If
   End Select
   Set Doc = iCollection.GetNextDocument(Doc)
  Wend  
 Case "NOTESVIEW":
  Set EntryList = iCollection.AllEntries
  Set Entry = EntryList.getFirstEntry
  While Not Entry Is Nothing
   Select Case Typename(Column)
   Case "INTEGER","LONG"
    If (Ubound(Entry.ColumnValues) >= Cint(Column)-1) Then
     ColumnValues = Entry.ColumnValues(Column-1)
     If (Isarray(ColumnValues)) Then
      Forall ColumnValue In ColumnValues
       Redim Preserve Results(Index&)
       Results(Index&) = ColumnValue
       Index& = Index& + 1
      End Forall
     Else
      Redim Preserve Results(Index&)
      Results(Index&) = ColumnValues
      Index& = Index& + 1
     End If
    End If
   Case "STRING"
    Redim Preserve Results(Index&)
    Set Doc = Entry.Document
    If (Doc.HasItem(Cstr(Column))) Then
     Results(Index&) = Doc.GetItemValue(Cstr(Column))(0)
     Index& = Index& + 1
    End If
   End Select
   Set Entry = EntryList.getNextEntry(Entry)
  Wend  
 End Select
 
 atfDBColumn = Results
 Exit Function
 
Catch:
 Stop
 Call ReportError
 Exit Function
 
End Function