Jan Schulz

dim manager  as Manager
set manager = person.getAdapter("MANAGER")
if manager is nothing then Error 1000, "Person is not a Manager!"
[...]

dim manager as Manager
if not (person isa ucase("Manager")) then error 1000, "Person is a not a manager!"
set manager = person
[...]

Class BaseObject
	' [ public function toString() as String ... ]

        '/**
	' * Returns an Adapter of the current Object of the aked-for type or nothing
	' * The basic implementation returns this object if the caller asked for the class 
        ' * or a subclass of the class of the current object
	' * Should be overwritten to do something more usefull!
	' * @autor Jan Schulz
	' */
	
	Public Function getAdapter(nameOfObject As String) As BaseObject
		If Ucase(nameOfObject) = Typename(Me) Then
			Set getAdapter = Me
		End If
		If Me Isa Ucase(nameOfObject) Then
			Set getAdapter = Me
		End If
	End Function
	
	
End Class

Use "class::logger"
Use "de.katzien.App.Infomail"
Use "de.katzien.App.InfomailDB"
Use "de.katzien.ls.Email"

Use "class::logger"
Use "de.katzien.App.InfomailDB"
Use "de.katzien.App.Infomail"
Use "de.katzien.ls.Email"

public function getSomething() as Something
  if oSomething is nothing then
    set oSomething = new Something()
  end if
  set getsomething = oSomething
end function

How do this with dynamic arrays? I was very surprised when this threw an error:

dim arrSomethings() as Something
if isArray(arrSomethings) then print ubound(arrSomething) ' unitialized array error when calling the ubound function 

You have to call a redim arrSomething(0 to 0) bevor you can do anything with that array. I tested it with every isXYZ function I could find in the designer help, but i couldn't find a way to detect that...Somehow I agree with Tommy Valand: LS Arrays are strange. Give me a Java collections like API and I'm happy :-)

BTW: datatype (arrSomething) gives "8738", even after the redim, but the designer help says that "8704" is a Dynamic array. Bug?

	Sub delegate_Queryopen(Source As Notesuidocument, Mode As Integer, Isnewdoc As Variant, Continue As Variant)
		Forall evhandler In listEventHandlers
			Call evHandler.Queryopen(Source , Mode, Isnewdoc , Continue )
			If Not Continue Then Exit Sub
		End Forall
	End Sub
	

Private Const ERR_ABSTRACT_INSTANTIATION = 1000
Private Const MSG_ABSTRACT_INSTANTIATION = | Attempt to instantiate as an object instance the abstract class |

Public Class BaseDocumentController
%REM
The Controller Part of MVC
Binds to a UIDocument, delegates all events to the EventHandlers
%END REM
	Private fUIDoc As NotesUIDocument
	Private fModel As BaseDocumentModel
	Private fIsInitialized As Boolean
	Private listEventHandlers List As AbstractDocumentEventHandler
	
	Sub new(uidoc As NotesUIDocument)
		If Not uidoc Is Nothing Then
			Call initializeWithUIDoc(uidoc)
		End If
	End Sub
	
	Public Function getUIDoc() As NotesUIDocument
		Set getUIDoc = fUIDoc
	End Function
	
	Public Function initializeWithUIDoc(uidoc As NotesUIDocument)
		If uiDoc Is Nothing Then
			Error 1111, "Need a UI Document"
		End If
		Set fUIDoc = uidoc
		Set fModel = New BaseDocumentModel( fUIDoc.Document)
		fIsInitialized = True
		
		Call bindEvents() 
		Call setupEventHandler()
		
		
	End Function
	
%REM
adds the default EventHandler (Validation) the to eventhandler List
Can be overwritten to extend the EventHandler List, needs to call
BaseDocumentController..setupEventHandler() to get the basic EventHandler 
setup or you need to add validation yourself
%END REM
	Function setupEventHandler()
		Dim evHandler As New ValidationHandler(fModel)
		Call Me.addEventHandler( "validation", evHandler)
		Dim evHandler2 As New AuditTrailHandler(fModel)
		Call Me.addEventHandler( "AuditTrail", evHandler2)		
	End Function
	
	Public Function addEventHandler(evName As String, evHandler As AbstractDocumentEventHandler)
		Set listEventHandlers(evName) = evHandler
	End Function
	
	Private Function bindEvents()
		On Event Queryopen From fUIDoc Call delegate_Queryopen
		On Event Postopen From fUIDoc Call delegate_Postopen
		On Event Querymodechange From fUIDoc Call delegate_Querymodechange	
		On Event Postmodechange From fUIDoc Call delegate_Postmodechange
		On Event Queryrecalc From fUIDoc Call delegate_Queryrecalc
		On Event Postrecalc From fUIDoc Call delegate_Postrecalc
		On Event Querysave From fUIDoc Call delegate_Querysave
		On Event Postsave From fUIDoc Call delegate_Postsave
		On Event Querysend From fUIDoc Call delegate_Querysend
		On Event Postsend From fUIDoc Call delegate_Postsend
		On Event Queryclose From fUIDoc Call delegate_Queryclose
		
	End Function
	
	Sub delegate_Queryopen(Source As Notesuidocument, Mode As Integer, Isnewdoc As Variant, Continue As Variant)
		Forall evhandler In listEventHandlers
			Call evHandler.Queryopen(Source , Mode, Isnewdoc , Continue )
			If Not Continue Then Exit Sub
		End Forall
	End Sub
	
	Sub delegate_Postopen(Source As Notesuidocument)
		Forall evhandler In listEventHandlers
			Call evHandler.PostOpen(Source)
		End Forall	
	End Sub
	
	Private Sub delegate_Querymodechange(Source As Notesuidocument, Continue As Variant)
		Forall evhandler In listEventHandlers
			Call evHandler.Querymodechange(Source, Continue)
			If Not Continue Then Exit Sub
		End Forall
	End Sub
	
	Private Sub delegate_Postmodechange(Source As Notesuidocument)
		Forall evhandler In listEventHandlers
			Call evHandler.Postmodechange(Source)
		End Forall
	End Sub
	
	Private Sub delegate_Queryrecalc(Source As Notesuidocument, Continue As Variant)
		Forall evhandler In listEventHandlers
			Call evHandler.Queryrecalc(Source, Continue)
			If Not Continue Then Exit Sub
		End Forall
	End Sub
	
	Private Sub delegate_Postrecalc(Source As Notesuidocument)
		Forall evhandler In listEventHandlers
			Call evHandler.Postrecalc(Source)
		End Forall
	End Sub
	
	Private Sub delegate_Querysave(Source As Notesuidocument, Continue As Variant)
		Forall evhandler In listEventHandlers
			Call evHandler.Querysave(Source, Continue)
			If Not Continue Then Exit Sub
		End Forall
	End Sub
	
	Private Sub delegate_Postsave(Source As Notesuidocument)
		Forall evhandler In listEventHandlers
			Call evHandler.Postsave(Source)
		End Forall
	End Sub
	
	Private Sub delegate_Querysend(Source As Notesuidocument, Continue As Variant)
		Forall evhandler In listEventHandlers
			Call evHandler.Querysend(Source, Continue)
			If Not Continue Then Exit Sub
		End Forall
	End Sub
	
	Private Sub delegate_Postsend(Source As Notesuidocument)
		Forall evhandler In listEventHandlers
			Call evHandler.Postsend(Source)
		End Forall
	End Sub
	
	Private Sub delegate_Queryclose(Source As Notesuidocument, Continue As Variant)
		Forall evhandler In listEventHandlers
			Print "Calling eventhandler for QueryClose"
			Call evHandler.Queryclose(Source, Continue)
			If Not Continue Then Exit Sub
		End Forall
		Print "End QueryClose"
	End Sub
	
End Class

Class BaseDocumentModel
%REM
The model part of MVC
Binds to the backend document and does validation (not implmented properly) and other stuff with the data
%END REM
	Private fDoc As NotesDocument
	Private fIsInitialized As Boolean
	
	Sub new(doc As NotesDocument)
		If Not doc Is Nothing Then
			Call initializeWithDocument(doc)
		End If
	End Sub
	
	Function initializeWithDocument(doc As NotesDocument)
		If doc Is Nothing Then
			Error 1111, "Model needs a Document"
		End If
		Set fDoc = doc
		fIsInitialized = True
	End Function
	
	Public Function validate() As ValidationResult
		If Not fIsInitialized Then Error 11111, "Uninitialised Model!"
		' Checks the model: something like a array of validation rules and the ValidationResult is passed to each rule to collect the result
		' Just for show:
		Set validate = New ValidationResult()
	End Function
	
End Class

Class validationResult
%REM
Collects the result of a validation
%END REM
	Sub new ()
		' Nothing to do
	End Sub
	Public Function addError(fieldname As String, Message As String)
		' unimplemented
	End Function
	Public Function hasErrors() As Boolean
		' unimplemented
		hasErrors = False
	End Function
	Public Function getFirstInvalidField() As String
		' unimplemented
		getFirstInvalidField = "Subject"
	End Function
	Public Function getFormattedErrorMessage() As String
		'unimplemented
		getFormattedErrorMessage = "Some Field: invalid"
	End Function
	
End Class

Public Class AbstractDocumentEventHandler 
%REM
Handels the delegated events from the Controller
Overwrite specific methods to let them do something
%END REM	
	Private fModel As BaseDocumentModel
	Public Sub New (model As BaseDocumentModel)
		Dim classname As String		
		Let className = Typename(Me)
		If (className = "ABSTRACTDOCUMENTEVENTHANDLER") Then
			Error ERR_ABSTRACT_INSTANTIATION, MSG_ABSTRACT_INSTANTIATION & classname
			Exit Sub
		End If
		Set Me.fModel = model
	End Sub
	
	Sub Queryopen(Source As Notesuidocument, Mode As Integer, Isnewdoc As Variant, Continue As Variant)
		' To be overwritten
	End Sub
	
	Sub Postopen(Source As Notesuidocument)
		' To be overwritten
	End Sub
	
	Public Sub Querymodechange(Source As Notesuidocument, Continue As Variant)		
		' To be overwritten
	End Sub
	
	Public Sub Postmodechange(Source As Notesuidocument)
		' To be overwritten
	End Sub
	
	Public Sub Queryrecalc(Source As Notesuidocument, Continue As Variant)
		' To be overwritten
	End Sub
	
	Public Sub Postrecalc(Source As Notesuidocument)
		' To be overwritten
	End Sub
	
	Public Sub Querysave(Source As Notesuidocument, Continue As Variant)
		' To be overwritten
	End Sub
	
	Public Sub Postsave(Source As Notesuidocument)
		' To be overwritten
	End Sub
	
	Public Sub Querysend(Source As Notesuidocument, Continue As Variant)
		' To be overwritten
	End Sub
	
	Public Sub Postsend(Source As Notesuidocument)
		' To be overwritten
	End Sub
	
	Public Sub Queryclose(Source As Notesuidocument, Continue As Variant)
		' To be overwritten
	End Sub
	
End Class

Public Class ValidationHandler As AbstractDocumentEventHandler 
%REM
Handels the validation of the model in the QuerySave Event, 
- stops saving when the model is not valid
- jumps to the first invalid field, as returned by the ValidationResult 
%END REM
	Sub new(model As BaseDocumentModel), AbstractDocumentEventHandler(model)
		' nothing to do, just pass the model on to parent class...
	End Sub
	
	Public Sub Querysave(Source As Notesuidocument, Continue As Variant)
		Print "doing validation"
		Dim oResult As ValidationResult
		Set oResult = fModel.validate()
		If oResult.hasErrors() Then
			Continue = Continue And False
			Msgbox oResult.getFormattedErrorMessage(), 0 , "Validation error"
			Call source.GoToField(oResult.getFirstInvalidField())
		End If
	End Sub
End Class


Public Class AuditTrailHandler As AbstractDocumentEventHandler 
%REM
Adds a comment to the backend document in the QuerySave Event, 
- This should better be done in an event in the Model: 
Controller -> QuerySave -> Everything validates, etc  -> model.QuerySave(....)  -> Calls a listener, which does the Trail or the model does it itself
-> even when you use the model without a controller, it gets a Trail
%END REM
	Sub new(model As BaseDocumentModel), AbstractDocumentEventHandler(model)
		' nothing to do, just pass the model on to parent class...
	End Sub
	
	Private Sub Querysave(Source As Notesuidocument, Continue As Variant)
		Print "Doing Audit"
		Dim sess As New NotesSession
		Dim newEdit As String
		Dim editType As String
		
		If (Source.IsNewDoc) Then
			Let editType = "created"
		Else
			Let editType = "modified"
		End If
		Let newEdit = Cstr(Now) & " - Document2 " & editType & " by " & sess.commonUserName
		Call Source.Document.ReplaceItemValue("AuditTrail", Fulltrim(Split(newEdit & Chr(13) & Join(Source.Document.GetItemValue("AuditTrail"), Chr(13)), Chr(13))))
	End Sub
End Class