Blogs

  • Browse Blogs
  • My Blog
  • My Updates

Tags Help

  • View as cloud  | list

Similar Blogs

photo

Lotus Nut

58 Entries |  Chris Whisonant
Updated 
Ratings 3     Comments 90
photo

Big A** Mutan...

42 Entries |  Michael Smelser
Updated 
Ratings 1     Comments 41
photo

McGarelGrammi...

12 Entries |  Mike McGarel
Updated 
No Ratings 0     Comments 11
photo

Yellow is the...

47 Entries |  Tim Tripcony
Updated 
No Ratings 0     Comments 14
photo

off the Hook

19 Entries |  Scott Hooks
Updated 
No Ratings 0     Comments 28

Archive

TexasSwede

Blog Authors:  Karl-Henry Martinsson  

All entries tagged with code_snippet

Parse URL in Domino agent

Karl-Henry Martinsson  |    |  Tags:  web code_snippet programming lotusscript  |  Comments (3)

Not Forum Friday, but Usenet Tuesday. :-)  A user in comp.groupware.lotus-notes.programmer had a question about generating Notes document remotely/in an automated way from another web application, using Perl:

 

> We have a Lotus Notes application and we would like to automate
> creating a new document or record in that application from another web
> based application.
>
> Here are the details:
> User action on web application triggers a PERL script to create a new
> record (document) in Lotus Notes (or Domino).

 

Here is my suggestion:

 

Create an agent that read the URL parameters you send to it.
Let's call the agent CreateNewDocument, and have two fields we want to fill out when the document is created. The Perl script can then call the URL like this:
 
 
The agent read the arguments and populate the corresponding fields, then save the document. I would highly recommend using a list to store the parameters, then you have a generic function you can re-use in any application.
In my article in the November/December 2006 issue of The View (starting on page 25) you have code for this.
 
Here is a class I just wrote to parse an incoming HTTP GET or POST. Put it in a script library called for example "URL.class":
 
Class URLclass
Public url As String
Private params List As String

Public Sub New()
  Dim session As New NotesSession
  Dim doc As NotesDocument
  Set doc = session.DocumentContext ' Document with all CGI variables
  ' Check if HTTP GET or POST was used...
  If Instr(doc.Query_String(0),"&") > 0 Then  ' GET was used
   url = doc.Query_String(0) 
  Elseif Instr(doc.Request_Content(0),"&") > 0 Then ' POST was used
   url = "&" & doc.Request_Content(0)
  Else          ' No parameters
   Exit Sub
  End If
End Sub

Public Function GetParams() As Variant
  Dim offset As Integer
  Dim startpos As Integer
  Dim midpos As Integer
  Dim endpos As Integer
  Dim nextpos As Integer
  Dim dataname As String
  Dim datavalue As String
  startpos = Instr(url,"&")    ' Start of first parameter
  Do While Not startpos = 0
   nextpos = Instr(startpos+1, url, "&") ' Start of next parameter
   If nextpos = 0 Then     ' We reached the end
    endpos = Len(url)+1
   Else
    endpos = nextpos
   End If
   midpos = Instr(startpos+1, url, "=") ' Position of = character
   dataname = Mid$(url,startpos+1,midpos-startpos-1)  ' Get name
   datavalue = Mid$(url,midpos+1,endpos-midpos-1)  ' Get value
   params(dataname) = datavalue   ' Add value to list
   startpos = nextpos     ' Set new start position
  Loop
  GetParams = params
End Function

End Class
 

Here is a sample agent that uses the class and print the arguments to the browser. Just expand on that code to create the document in the database:

 

Option Public
Option Declare
Use "URL.class"
 

Sub Initialize
 Dim url As New URLclass

 Dim params As Variant
 params = url.GetParams()
 Forall x In params
   Print Listtag(x) & " = " & params(Listtag(x)) & "<br>"
 End Forall
End Sub

 

The LotusScript was converted to HTML using the ls2html routine,
provided by Julian Robichaux at nsftools.com.

Skip to main content link. Accesskey S
IBM Lotus Connections Help Tools About

Tags

A tag is a keyword that is used to categorize an entry. To view the entries with a particular tag, click a tag name or enter a tag in the box.
The tag cloud indicates the frequency of tag use. Popular tags appear darkest. The slider control adjusts how many tags are displayed in the tag cloud.